mirror of
git://repo.or.cz/tinycc.git
synced 2026-06-17 15:44:18 +08:00
6694391b74
Some checks are pending
build and test / test-x86_64-linux (push) Waiting to run
build and test / test-x86_64-osx (push) Waiting to run
build and test / test-aarch64-osx (push) Waiting to run
build and test / test-x86_64-win32 (push) Waiting to run
build and test / test-i386-win32 (push) Waiting to run
build and test / test-armv7-linux (push) Waiting to run
build and test / test-aarch64-linux (push) Waiting to run
build and test / test-riscv64-linux (push) Waiting to run
I updated the tests/gcctestsuite.sh a bit. before: 3329 test(s) ok. 210 test(s) skipped. 168 test(s) failed. 28 test(s) exe failed. after: 3331 test(s) ok. 299 test(s) skipped. 79 test(s) failed. 26 test(s) exe failed. I found some small problems: include/tccdefs.h: Add alloca definition for i386 and x86_64 lib/alloca.S/lib/alloca-bt.S: align i386 alloca to 16 bytes. i386_gen.c vla code and gcc do the same. x86_64-gen.c: fix typo in comment
87 lines
1.4 KiB
ArmAsm
87 lines
1.4 KiB
ArmAsm
/* ---------------------------------------------- */
|
|
/* alloca.S */
|
|
|
|
#ifdef __leading_underscore
|
|
# define _(s) _##s
|
|
#else
|
|
# define _(s) s
|
|
#endif
|
|
|
|
/* ---------------------------------------------- */
|
|
#if defined __i386__
|
|
|
|
.globl _(alloca), _(__alloca)
|
|
_(alloca):
|
|
_(__alloca):
|
|
push %ebp
|
|
mov %esp,%ebp
|
|
mov 8(%ebp),%eax
|
|
add $15,%eax
|
|
and $-16,%eax
|
|
sub $4,%eax
|
|
#ifdef _WIN32
|
|
jmp .+16 #p2
|
|
p1:
|
|
sub $4096,%esp
|
|
sub $4096,%eax
|
|
test %eax,(%esp)
|
|
p2:
|
|
cmp $4096,%eax
|
|
jae p1
|
|
#endif
|
|
sub %eax,%esp
|
|
mov 4(%ebp),%eax
|
|
mov 0(%ebp),%ebp
|
|
add $8,%esp
|
|
push %eax
|
|
lea 8(%esp),%eax
|
|
ret
|
|
|
|
/* ---------------------------------------------- */
|
|
#elif defined __x86_64__
|
|
|
|
.globl _(alloca)
|
|
_(alloca):
|
|
pop %rdx
|
|
#ifdef _WIN32
|
|
mov %rcx,%rax
|
|
#else
|
|
mov %rdi,%rax
|
|
#endif
|
|
add $15,%rax
|
|
and $-16,%rax
|
|
jz p3
|
|
|
|
#ifdef _WIN32
|
|
p1:
|
|
cmp $4096,%rax
|
|
jbe p2
|
|
test %rax,-4096(%rsp)
|
|
sub $4096,%rsp
|
|
sub $4096,%rax
|
|
jmp p1
|
|
p2:
|
|
#endif
|
|
sub %rax,%rsp
|
|
mov %rsp,%rax
|
|
p3:
|
|
push %rdx
|
|
ret
|
|
|
|
/* ---------------------------------------------- */
|
|
#elif defined __arm__
|
|
|
|
.text
|
|
.align 2
|
|
.global alloca
|
|
.type alloca, %function
|
|
alloca:
|
|
rsb sp, r0, sp
|
|
bic sp, sp, #7
|
|
mov r0, sp
|
|
mov pc, lr
|
|
.size alloca, .-alloca
|
|
|
|
/* ---------------------------------------------- */
|
|
#endif
|